Skip to content

Commit

Permalink
Browse files Browse the repository at this point in the history
[util] Add romcheck.pl
Provide a utility to quickly determine the ROM size and .mrom format
support for attached PCI devices.  For example:

    01:00.0 (1186:4300) supports a 128kB .rom or .mrom

Inspired-by: Wes Frazier <wes.frazier@members.fsf.org>
Signed-off-by: Michael Brown <mcb30@ipxe.org>
  • Loading branch information
mcb30 committed Sep 19, 2011
1 parent 469bd11 commit 8b092f4
Showing 1 changed file with 54 additions and 0 deletions.
54 changes: 54 additions & 0 deletions src/util/romcheck.pl
@@ -0,0 +1,54 @@
#!/usr/bin/perl -w

use strict;
use warnings;

use constant DEVICES => "/proc/bus/pci/devices";

open my $fh, DEVICES
or die "Could not open ".DEVICES.": $!";

while ( ( my $line = <$fh> ) ) {

# Parse line from /proc/bus/pci/devices
chomp $line;
( my $bus, my $devfn, my $vendor, my $device, my $irq, my $bars, my $lengths,
my $driver )
= ( $line =~ /^ ([0-9a-f]{2}) ([0-9a-f]{2}) \s+
([0-9a-f]{4}) ([0-9a-f]{4}) \s+ ([0-9a-f]+) \s+
((?:[0-9a-f]+\s+){7}) ((?:[0-9a-f]+\s+){7})
(.+)?$/x )
or die "Invalid line \"".$line."\"\n";
( $bus, $devfn, $vendor, $device, $irq ) =
map { hex ( $_ ) } ( $bus, $devfn, $vendor, $device, $irq );
my $dev = ( $devfn >> 3 );
my $fn = ( $devfn & 0x7 );
$bars = [ map { hex ( $_ ) } split ( /\s+/, $bars ) ];
$lengths = [ map { hex ( $_ ) } split ( /\s+/, $lengths ) ];

# Calculate expansion ROM BAR presence and length
my $rom_length = $lengths->[6];

# Look for a BAR that could support a .mrom
my $mrom_ok;
if ( $rom_length ) {
for ( my $bar = 0 ; $bar < 7 ; $bar++ ) {
# Skip I/O BARs
next if $bars->[$bar] & 0x01;
# Skip low half of 64-bit BARs
$bar++ if $bars->[$bar] & 0x04;
# Skip 64-bit BARs with high dword set
next if $bars->[$bar] >> 32;
# Skip BARs smaller than the expansion ROM BAR
next if $lengths->[$bar] < $rom_length;
# This BAR is usable!
$mrom_ok = 1;
last;
}
}

printf "%02x:%02x.%x (%04x:%04x)", $bus, $dev, $fn, $vendor, $device;
printf " supports a %dkB .rom", ( $rom_length / 1024 ) if $rom_length;
printf " or .mrom" if $mrom_ok;
printf "\n";
}

0 comments on commit 8b092f4

Please sign in to comment.